2.3. Команды десятичной коррекции неупакованных чисел

Для неупакованных чисел или, как их еще называют ASCII-чисел, существуют аналогичные команды коррекции после сложения – aaa и вычитания – aas. Сложение и вычитание ASCII-чисел также выполняется в два этапа.

Кроме того, над ASCII-числами допустимо выполнение опера­ций умножения и деления.

Умножение ASCII-чисел выполняется в два этапа:

• умножение одноразрядных сомножителей, представленных байтами, в которых младшие тетрады содержат десятичные цифры, а старшие тетрады – нулевые. Умножение выполняется командой mul, которая формирует в регистре AL двоичное про­изведение;

• коррекция результата с помощью команды aam, которая преоб­разует полученный результат в двухбайтовое произведение, на­ходящееся в регистрах AH (старший десятичный разряд) и AL (младший разряд).

Деление также выполняется в два этапа, но в отличие от ос­тальных команд коррекция выполняется не после, а перед вы­полнением операции:

• коррекция делимого с помощью команды aad, которая предполагает, что в регистрах AH и AL находится двухразрядное делимое, причем AH содержит цифру десятков, а AL – цифру единиц и обе старшие тетрады нулевые. Она формирует в AX соответствующее двоичное число;

• деление полученного в AX делимого на одноразрядный дели­тель, с получением частного в AL и остатка в AH.

3. Пример выполнения работы

Написать программу сложения двух десятиразрядных неупако­ванных десятичных чисел.

Текст программы:

model SMALL

stack 100h

dataseg

Ask1 db 0Ah,0Dh,'Введите первое слагаемое (не более 10 цифр):$'

Ask2 db 0Ah,0Dh,'Введите второе слагаемое (не более 10 цифр):$'

Buf1 db 11

Len1 db ?

Opnd1 db 12 dup( ? )

Buf2 db 11

Len2 db ?

Opnd2 db 12 dup( ? )

ResT db 0Ah,0Dh,'Сумма'

Res db 12 dup(' '),'$'

AskCont db 0Ah,0Dh

db 'Завершить работу- Esc, продолжить - ЛЮБАЯКЛАВИША'

db '$'

codeseg

startupcode

push DS

pop ES ; ES <- DS

BEGIN:

;Ввод первого слагаемого

B1: lea DX, Ask1

mov AH, 09h

int 21h

lea DX, Buf1

mov AH, 0Ah

int 21h

cmp Len1, 0

je B1

;проверка 0-9 и очистка старш.тетрады

lea BX, Opnd1

xor CX, CX

mov CL, Len1

xor SI, SI

T1: mov AL, [BX][SI]

cmp AL, '0'

jb B1 ; ошибка

cmp AL, '9'

ja B1 ; ошибка

and AL, 0Fh

mov [BX][SI], AL

inc SI

loop T1

;прижать к правому краю

mov CL, Len1

cmp CL, 10

je E1

mov DI, 9

mov SI, CX

dec SI

P1: mov AL, [BX][SI]

mov [BX][DI], AL

dec DI

dec SI

loop P1

;обнулить лишнее

xor DI, DI

mov CL, 10

sub CL, Len1

N1: mov byte ptr [BX][DI], 0

inc DI

loop N1

E1:

;Ввод второго слагаемого

B2: lea DX, Ask2

mov AH, 09h

int 21h

lea DX, Buf2

mov AH, 0Ah

int 21h

cmp Len2, 0

je B2

;проверка 0-9 и очистка старш.тетрады

lea BX, Opnd2

xor CX, CX

mov CL, Len2

xor SI, SI

T2: mov AL, [BX][SI]

cmp AL, '0'

jb B2 ; ошибка

cmp AL, '9'

ja B2 ; ошибка

and AL, 0Fh

mov [BX][SI], AL

inc SI

loop T2

;прижать к правому краю

mov CL, Len2

cmp CL, 10

je E2

mov DI, 9

mov SI, CX

dec SI

P2: mov AL, [BX][SI]

mov [BX][DI], AL

dec DI

dec SI

loop P2

;обнулить лишнее

xor DI, DI

mov CL, 10

sub CL, Len2

N2: mov byte ptr [BX][DI], 0

inc DI

loop N2

E2:

;Сложение

mov CX, 10

clc

lea SI, Opnd1+9

lea DI, Opnd2+9

lea BX, Res+10

A1: mov AL, [SI]

adc AL, [DI]

aaa

mov [BX], AL

dec SI

dec DI

dec BX

loop A1

mov AL, 0

adc AL, 0

mov [BX], AL

;Преобразование результата в ASCII

mov CX, 11

A2: or byte ptr [BX], 30h

inc BX

loop A2

;Вывод результата

lea DX, ResT

mov AH, 09h

int 21h

;Запрос на продолжение работы

lea DX, AskCont

mov AH, 09h

int 21h

mov AH, 08h

int 21h

cmp AL, 27 ;ESC

je QUIT

jmp BEGIN

;Конец работы

QUIT: exitcode 0

end