ПолучитьИтог

Выбрать очередной остаток по регистру.

Синтаксис:

ПолучитьИтог()

Англоязычный синоним:

GetTotal

Возвращаемое значение:

Число: 1 — если очередной остаток по регистру выбран успешно; 0 — если очередной остаток по регистру не найден (отсутствует).

Описание:

Метод ПолучитьИтог выбирает очередной остаток по регистру в последо­вательности выборки, открытой перед этим при помощи метода ВыбратьИто­ги. Данный метод используется для организации цикла по регистру — позволя­ет перебрать текущие или временные (см. ВременныйРасчет) остатки по ре­гистру. При этом используется фильтр, если он установлен (см. УстановитьФильтр). Открывается выборка остатков по всем записанным зна­чениям измерений.

Итоги с нулевыми остатками не выдаются. Порядок выдачи для измерений типа «справочник» и «документ» не определен.

После выполнения данного метода все атрибуты регистра: измерения, ре­сурсы, Приход и Расход содержат значения очередной записи остатков реги­стра. Данный метод может использоваться только для позиционируемых объек­тов, созданных функцией СоздатьОбъект.

Пример:

Процедура ВыбратьКредит()

Список = СоздатьОбъект("СписокЗначений");

Рег = СоздатьОбъект("Регистр.ТоварныйКредит");

Рег.УстановитьФильтр(Клиент, );

Ном = 0;

Рег.ВыбратьИтоги();

Пока Рег.ПолучитьИтог() = 1 Цикл

Док = Рег.Документ;

Список.ДобавитьЗначение(Док, "" + Док + " — Остаток = " + Рег.Долг);

Если Ном = 0 Тогда

ВыбДок = Док;

КонецЕсли;

Ном = Ном + 1;

КонецЦикла;

Если Ном > 0 Тогда

Если Список.ВыбратьЗначение(ВыбДок, "Выберите кредит") = 1 Тогда

ДокКредита = ВыбДок;

КонецЕсли;

КонецЕсли;

КонецПроцедуры

См. также: ВыбратьИтоги

ВыгрузитьИтоги

Выгрузить все итоги регистра с текущим фильтром в таблицу значений.

Синтаксис:

ВыгрузитьИтоги(<Та6лЗнач>, <ВключатьИзмерФильтра>, <ПредварительноОчищать>)

Англоязычный синоним:

RetrieveTotals

Параметры:

<ТаблЗнач>	Объект типа ТаблицаЗначений, куда сис­тема выгрузит все итоги регистра.
<ВключатьИзмерФильтра>	Необязательный параметр. Число: 1 — в получаемую таблицу включаются измере­ния, закрепленные фильтром; 0 — не включаются. Значение по умолчанию — 0.
<ПредварительноОчищать>	Необязательный параметр. Число: 1 — пе­ред выгрузкой таблица значений очищает­ся; 0 — не очищается. Значение по умолча­нию — 1.

Описание:

Метод ВыгрузитьИтоги выгружает все итоги регистра с текущим фильт­ром (см. УстановитьФильтр) в таблицу значений.

Пример:

Функция ВыбратьКредит(ВыбКлиент)

Список = СоздатьОбъект("ТаблицаЗначений");

Рег = СоздатьОбъект("Регистр.ТоварныйКредит");

Рег.УстановитьФильтр(ВыбКлиент, );

Рег.ВыгрузитьИтоги(Список, 1);

Возврат Список;

КонецФункции

См. также: УстановитьФильтр

ВременныйРасчет

Установить флаг участия регистра во временном расчете.

Синтаксис:

ВременныйРасчет(<Флаг>)

Англоязычный термин:

TempCalc

Параметры:

<Флаг>

Необязательный параметр. Числовое выражение. 1 — установить флаг участия регистра во временном расчете; 0 — сбросить флаг участия регистра во временном расчете. Значение по умолчанию — 1.

Возвращаемое значение:

Текущее числовое значение флага участия регистра во временном расчете.

Описание:

Метод ВременныйРасчет устанавливает флаг участия регистра во времен­ном расчете. После такой установки можно выполнять процедуры рассчитатьРегистрыНа и РассчитатьРегистрыПо, тогда у данного регист­ра методы обращения к остаткам будут выдавать рассчитанные значения остат­ков на заданный момент времени.

Замечание. В один момент времени только по одному объекту регистров каж­дого вида могут участвовать во временном расчете.

Пример:

// если итоги не актуальны, то стоимости берем из временного расчета

// регистра УчетРеализации

Рег = СоздатьОбъект("Регистр.УчетРеализации");

Рег.ВременныйРасчет();

РассчитатьРегистрыНа(ТекущийДокумент());

Рег.Товар = Товар;

Рег.Клиент = Клиент;

Рег.ОстаткиПолучить();

ТекОстаток = Рег.ОстатокТовара;

ТекСтоимость = Рег.Стоимость;

ТекПродСтоимость = Рег.ПродСтоимость;

См. также: РассчитатьРегистрыНа, РассчитатьРегистрыПо